Does Dr. J know when to quit, or will he continue to flounder in his deep morass of Fractal Jello. The more he looks for his roots the more he finds. He is using Newton's method which locates roots of equations. Tonight there are 12 roots. What do you think will happen when Dr. J discovers there are potentially infinitely many?
|
Figure 1. More Fractal Jello.
Now, a little math. Please consult last times discussion some background analysis. Recall, we are iterating a function
1) z:=f(z, c)
Tonight, I selected for f(z, c) is an twelfth degree polynomial, Eqn 2. For Newton's method and the critical points, we need to use calculus and obtain derivatives of f, Eqns 3 and 4.
2) f(z,c) = z12 - A*z11 - z*c + A*c
3) f'(z,c) = 12z11 - 11A*z10 - c
4) f"(z) = 132z10 - 110A*z9
We are using initial values of z the critical points which are solutions of f"(z)=0. (The ' and " indicate first and second derivatives.)
5) 132z010 - 110A*z09 = 22z09(6z0 - 5A) = 0.
So z0 = 5A/6. It turns out that for Eqn 2) we can write down the solutions, or roots as they are called. f(z,c) can be factored (that was planned) into
6) f(z, c) = (z - A)(z11 - c)
so that when z = A, or z = c1/11, f(z, c)=0 is satisfied. Paul's method uses the known roots as selectors of color ranges.
Here are more quiz questions:
Are there Misiurewicz points in Figure 1? Can you identify any?
What would Julia sets if this function , Eqn 1, look like?
Is Dr. J in any condition to supply answers any time soon? So far, only Peter Jakubowicz has ventured a reply to a quiz question. :-)
Stay warm,
Jay
The parameter and formula files for Fractint are included below. Copy them
into a quickie.par file for quick loading into Fractint. For longer term
use, copy the frm: block into a FotN.frm file. But this time leave off the
'frm:' part. Then copy the rest (the par parts) into your FotN.par
file.
frm:Newt12-JAtan-Mset {; (c) Jay R. Hill, 1998
; Newton method set up as a Mandelbrot set
; This formula searches for 12 roots of a function
; Inspired by Paul Carlson's Newt5_Atan_Mset
; p1=width of root finding
; p2=A=constant in formula
; F(w) = w^12 - A*w^11 - w*c + A*c
; F'(w) = 12*w^11 - 11*A*w^10 - c
; F''(w) = 132*w^10 - 110*A*w^9
; Set F''=0, solve for initial w, 110*A/132 = 5*A/6
;
c = pixel, A=p2, z = iter = bailout = 0
colors_in_range = 21
R=(-1)^(2/11), R2=sqr(R)
root1 = A, root2 = c^(1/11), root3 = root2*R, root4 = root2*R2
root5 = root4*R, root6 = root4*R2, root7 = root6*R, root8 = root6*R2
root9 = root8*R, root10 = root8*R2, root11 = root10*R, root12 = root10*R2
w = 5*A/6
:
w10 = w^10
deltaw=((w*w10 - A*w10 - c)*w + A*c)/(12*w*w10 - 11*A*w10 - c)
w = w - deltaw
;
IF (|deltaw| < p1)
angle=abs(imag(log(deltaw)))
range_num = (|w - root2| < p1)+2*(|w - root3| < p1)+\
3*(|w - root4| < p1)+ 4*(|w - root5| < p1)+5*(|w - root6| < p1)+\
6*(|w - root7| < p1)+ 7*(|w - root8| < p1)+\
8*(|w - root9| < p1)+ 9*(|w - root10| < p1)+\
10*(|w - root11| < p1)+11*(|w - root12| < p1)
bailout = 1
z = colors_in_range*(angle/pi + range_num)-angle/pi + 1
ENDIF
iter = iter + 1
z = z - iter
bailout == 0
}
jn12atnm001n { ; (C) by Jay Hill, 1998
; Ribbon Jello
reset=1960 type=formula formulafile=n6jatnm.par
formulaname=newt12-jatan-mset
center-mag=-0.298069/-0.181754/46.17689/1/-90 params=1e-005/0/1/0
float=y maxiter=2000 inside=253 outside=summ
colors=000000<19>w00000<19>wUL000<19>ww1000<19>Uw0090<19>0w0000<19>0wU00\
0<19>7ww000<19>0Uw000<19>00w00w000<18>U0w000<19>w0w000<19>w0UwZA000000
cyclerange=1/252
}
