Dr. J continues to flounder in a morass of Fractal Jello. It is much like quicksand, becoming even more muddled the more he struggles. I'd like to just ignore him, I think he is going to have to figure this out for himself. When he became mired down in his search for his Roots a few days ago, there were just six roots, each spouting a different color of Fractal Jello. At least that is what it looks like to me. You recall, he is using Newton's method which locates roots of equations. Well, anyway, tonight he has found two more roots which started spouting two more colors to the six he had.
|
Figure 1. Deeper Fractal Jello.
Now, a little math. Please consult last times discussion some background analysis. Recall, we are iterating a function
1) z:=f(z, c)
Tonight, I selected for f(z, c) is an eighth degree polynomial, Eqn 2. For Newton's method and the critical points, we need to use calculus and obtain derivatives of f, Eqns 3 and 4.
2) f(z,c) = z8 - A*z7 - z*c + A*c
3) f'(z,c) = 8z7 - 7A*z6 - c
4) f"(z) = 56z6 - 42A*z5
We are using initial values of z the critical points which are solutions of f"(z)=0. (The ' and " indicate first and second derivatives.)
5) 56z06 - 42A*z05 = 14z05(4z0 - 3A) = 0.
So z0 = 3A/4. It turns out that for Eqn 2) we can write down the solutions, or roots as they are called. f(z,c) can be factored (that was planned) into
6) f(z, c) = (z - A)(z7 - c)
so that when z = A, or z = c1/7, f(z, c)=0 is satisfied. Paul's method uses the known roots as selectors of color ranges.
Here are more quiz questions:
Since the parameter, A, is only a scaling factor and may as well be ignored, are the little midgets showing up in this fractal fixed? If not, how can we change their positions?
The classic Mandelbrot set displays bands around the Cardioid and buds, known as escape time contours. What are the contours in this fractal and are they basically the same as the escape contours? Please explain.
Can Dr. J supply answers next time (or is he totally gagged on Jello....).
Stay warm,
Jay
The parameter and formula files for Fractint are included below. Copy them
into a quickie.par file for quick loading into Fractint. For longer term
use, copy the frm: block into a FotN.frm file. But this time leave off the
'frm:' part. Then copy the rest (the par parts) into your FotN.par
file.
frm:Newt8-JAtan-Mset {; (c) Jay R. Hill, 1998
; Newton method set up as a Mandelbrot set
; This formula searches for 8 roots of a function
; Inspired by Paul Carlson's Newt5_Atan_Mset
; p1=width of root finding
; p2=A=constant in formula
; F(w) = w^8 - A*w^7 - w*c + A*c
; F'(w) = 8*w^7 - 7*A*w^6 - c
; F''(w) = 56*w^6 - 42*A*w^5
; Set F''=0, solve for initial w, 42*A/56 = 3*A/4
;
c = pixel, A=p2, z = iter = bailout = 0
colors_in_range = 31
R=(-1)^(2/7), R2=sqr(R)
root1 = A, root2 = c^(1/7), root3 = root2*R, root4 = root2*R2
root5 = root4*R, root6 = root4*R2, root7 = root6*R, root8 = root6*R2
w = 3*A/4
:
w6 = w^6
deltaw=((w*w6 - A*w6 - c)*w + A*c)/(8*w*w6 - 7*A*w6 - c)
w = w - deltaw
;
IF (|deltaw| < p1)
angle=abs(imag(log(deltaw)))
range_num = (|w - root2| < p1)+2*(|w - root3| < p1)+\
3*(|w - root4| < p1)+4*(|w - root5| < p1)+5*(|w - root6| < p1)+\
6*(|w - root7| < p1)+7*(|w - root8| < p1)
bailout = 1
z = colors_in_range*(angle/pi + range_num)-angle/pi + 1
ENDIF
iter = iter + 1
z = z - iter
bailout == 0
}
jn8atnm002nb { ; (C) by Jay Hill, 1998
; bright colors
; found a midget
reset=1960 type=formula formulafile=n6jatnm.par
formulaname=newt8-jatan-mset
center-mag=-0.287268/-0.119429/51.47021/1/-90 params=0.01/0/1/0
float=y maxiter=2000 inside=253 outside=summ
colors=000w00<28>2000000w0<28>02000000w<29>000ww0<28>220000000<29>w0w000\
<29>0ww000<28>uuuwwwwU0<28>210000000<2>000wmU000000
cyclerange=1/248
savename=Jn8atn2b.gif
}
